Программирование Викиданных/Академии и научные сообщества

Количество объектов "Академия"

Объекты: академия (Q162633)

Выведем все академии, содержащиеся в Викиданных.

# academy 
SELECT ?academy ?academyLabel WHERE {
    ?academy wdt:P31 wd:Q162633.    # academy
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}

SPARQL-запрос, 282 записи на 17 октября 2018 года.

Итого, 282 академии существует в мире.

Построим дендрограмму с кластеризацией академий по их количеству в странах.

Кластерная дендрограмма с количеством академий в странах мира, построенная с помощью RAWGraphs, 2018

# academy 
#defaultView:BarChart
SELECT ?country ?countryLabel (count(?academy) as ?count)
WHERE
{
    ?academy  wdt:P31 wd:Q162633.
    ?academy wdt:P17 ?country.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "ru" }
 }
GROUP BY ?countryLabel ?country
ORDER BY DESC (?count)

SPARQL-запрос, 56 стран, у которых есть академии.

Больше трёх академий имеют всего лишь 9 страны:

Испания ‒ 39
Бразилия ‒ 17
Италия ‒ 14
Германия ‒ 13
Франция ‒ 11
Россия ‒ 11
Бельгия ‒ 6
Великобритания ‒ 5
Украина ‒ 4.

35 стран имеют только одну академию.

Академии России

Написать скрипт и перечислить академии: Российской империи, СССР и России.

Количество отечественных математиков (Российская империя, СССР, Россия)

Объекты: математик (wd:Q170790)

Выведем список отечественных математиков.

SPARQL-запрос 1423 записи на 30 октября 2018 года.

Полученных результат (1423 математика) больше, чем значение в таблице "WP Person math"(1051 математик).

Получим суммарное число академий, куда входят отечественные математики:

#russian mathematicians
SELECT ?mathematician ?mathematicianLabel (count(?academy) as ?count)
WHERE {
    ?mathematician wdt:P106 wd:Q170790.    
     #country of citizenship
    { ?mathematician wdt:P27 wd:Q34266 } UNION  # Russian Empire
    { ?mathematician wdt:P27 wd:Q15180 } UNION  # Soviet Union
    { ?mathematician wdt:P27 wd:Q159 }.         # Russia
     ?mathematician wdt:P463 ?academy.
                                          
    SERVICE wikibase:label { bd:serviceParam wikibase:language "ru" }
}
GROUP BY ?mathematician ?mathematicianLabel
ORDER BY DESC (?count)

Выполнить запрос (ru)

Всего академий 1219 (на 30 октября 2018 года).

Открытый вопрос: найти число разных академий, куда входят отечественные математики. Пример: Иванов входит в академии A, B, C, Петров ‒ в академии A, B, то суммарное число будет 3.

География академий

# Number of academies in countries
#defaultView:Map
SELECT ?academy ?academyLabel ?academyDescription ?website ?location
WHERE
{
      {?academy wdt:P31 wd:Q414147} UNION  # academy of sciences
      {?academy wdt:P31 wd:Q955824} UNION  # learned society
      {?academy wdt:P31 wd:Q748019} UNION # scientific society
      {?academy wdt:P31 wd:Q31855} UNION  # research institute
      {?academy wdt:P31 wd:Q2385804} UNION  # educational institution
      {?academy wdt:P31 wd:Q162633} UNION  # academy
      {?academy wdt:P31 wd:Q43229}.  # organization
    ?academy wdt:P625 ?location #display location
    OPTIONAL {
		?academy wdt:P856 ?website
	}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "ru" }
 }

Выполнить запрос (ru)

Всего 13392 географических точек академий мира (на 22 февраля 2019 года).