Программирование Викиданных/Ядерные катастрофы

Морозько Андрей

Экземпляры объекта "Ядерные катастрофы"

• Объекты: nuclear disaster (Q15725976), nuclear and radiation accident (Q1620824)

Построим список всех ядерных катастроф и происшествий.

#added 2017-02
SELECT ?disaster ?disasterLabel
WHERE
{
  {
    ?disaster wdt:P31 wd:Q15725976.  #`instance of` "nuclear disaster"
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
  } UNION {
    ?disaster wdt:P31 wd:Q1620824.   #`instance of` "nuclear and radiation accident" 
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
  }
}

SPARQL query 13 Results

Список объектов "nuclear disaster": SPARQL query 4 Results

Список объектов "nuclear and radiation accident": SPARQL query 9 Results

👍 Наиболее полными и проработанными объектами по темам на Викиданных являются: Chernobyl disaster, Fukushima nuclear accident, Three Mile Island accident

👎 Почти пустыми и малоинформативными оказались: Samut Prakan radiation accident, Béryl incident, Windscale fire

В полученном списке есть 3 объекта без имени. Получим список объектов, у которых поле "label" будет непустым.

#added 2017-02
SELECT ?disaster ?disaster_label
WHERE
{
  {
    ?disaster wdt:P31 wd:Q15725976.  #`instance of` "nuclear disaster"
  } UNION {
    ?disaster wdt:P31 wd:Q1620824.   #`instance of` "nuclear and radiation accident" 
  }
  ?disaster rdfs:label ?disaster_label  
  FILTER (LANG(?disaster_label) = "en").
}

SPARQL query 10 Results

Задачи

Объекты: nuclear disaster (Q15725976), nuclear and radiation accident (Q1620824)

Список ядерных катастроф, отсортированных по числу смертей

• Свойство: number of deaths (P1120)

#added 2017-03
SELECT ?disaster ?name ?number_of_deaths
WHERE
{
  {
    ?disaster wdt:P31 wd:Q15725976.  #`instance of` "nuclear disaster"
  } UNION {
    ?disaster wdt:P31 wd:Q1620824.   #`instance of` "nuclear and radiation accident" 
  }
  OPTIONAL {
	?disaster rdfs:label ?name
	filter (lang(?name) = "en")
  }
  OPTIONAL {
	?disaster wdt:P1120 ?number_of_deaths  #`number of deaths`
  }
}
ORDER BY DESC(?number_of_deaths)

SPARQL query

Построить пузырьковую диаграмму по количеству ядерных происшествий в стране

• Свойство: country (P17)

#added 2017-03
#defaultView:BubbleChart
SELECT ?country_name (count(*) as ?count)
WHERE
{
  {
    ?disaster wdt:P31 wd:Q15725976.  #`instance of` "nuclear disaster"
  } UNION {
    ?disaster wdt:P31 wd:Q1620824.   #`instance of` "nuclear and radiation accident" 
  }  
  ?disaster wdt:P17 ?country.        #`country`
  ?country rdfs:label ?country_name
  filter (lang(?country_name) = "en").
  
}
GROUP BY ?country_name 
ORDER BY DESC(?count)

SPARQL query

Построить карту ядерных происшествий

#added 2017-03
#defaultView:Map
SELECT ?country_name ?location
WHERE
{
  {
    ?disaster wdt:P31 wd:Q15725976.  #`instance of` "nuclear disaster"
  } UNION {
    ?disaster wdt:P31 wd:Q1620824.   #`instance of` "nuclear and radiation accident" 
  }  
  ?disaster wdt:P625 ?location.      #`coordinate location`
}

SPARQL query

Полнота Викиданных

В мире произошло 68 событий уровня INES 3 и выше и 13 событий уровня INES 4 и выше.

В викиданных есть объекты для большинства событий уровня INES 4 и выше.

В Русской Википедии описано 33 события. В Английской Википедии описано 28 событий.

Не существует однозначной статистики радиационных аварий, потому что:

1. Единая классификация INES появилась лишь в 1991 году, многие предыдущие инциденты остаются без официального уровня
2. В официальных признаках классификации используются размытые термины
3. Некоторые инциденты засекречены
4. В некоторых случаях аварии в разных блоках АЭС объединяются в один инцидент, а в других – нет

Литература

Minh Ha-Duong; V. Journé Calculating nuclear accident probabilities from empirical frequencies (2014). Проверено 8 марта 2017.